VALID TRIGGER TYPES

ACT

Keyword : ‘ACT‘

Argument: string The argument is a phrase, a text string. The trigger is activated whenever the phrase is contained in the act() message. NOTE: Most general trigger. Applies to almost every event which happens in the mud. Anytime the function act() is called with a message to be delivered TO_CHAR,TO_VICT,TO_ROOM,etc. the act can be triggered. Basically this will trigger on almost everything you’ll ever want. Output of “say”, “shout” and “emote” do not trigger this event. IE: ‘addmprog 1234 act “looks at you” 100’

SPEECH

Keyword : ‘SPEECH‘

Argument: (word) or “(string)” NOTE: This is only triggered when the phrase is contained in a message which has been said by a PC in the same room as the mob. The PC restriction is not necessary, but makes infinite loops between two talking mobiles impossible. It also makes it impossible for two NPC’s to stand and discuss the weather however. IE: ‘addmprog 1234 speech “Hello there” 100’ (then mprog has a speech or action etc, happens 100% of the time when someone says ‘hello there’)

RANDOM

Keyword : ‘RANDOM‘

Argument: number (percentage to trigger) NOTE: This trigger is checked at each PULSE_MOBILE and if the argument is greater than a percentage roll the trigger is activated. This will happen even if there is no PC in the room with the mob, but there must be players in the same area. It is useful to give mobiles a bit of a personality. For instance a janitor who stops to spit tobacco, or complain about the hours, or wonder why there are no woman janitors on muds, or a fido which barks or growls or pees on the curb is much more alive than one which just sits there scavenging. Note that this trigger is checked only when there are players in the area. If you want this event to be triggered always, you must set the ACT UPDATE_ALWAYS flag of the mobile. **** JUST A WARNING TO THE WISE ON RANDOM AND UPDATE_ALWAYS **** On further testing, using it on an update_always mob causes “MAX CALL EXCEEDED” errors profusely. Let’s just say the error log was 4.3 megs for ONE day. If you do decide to use random on an UPDATE_ALWAYS mob, set the random to something like 1-3% and DON’T make too many of these mobs (like 1 or 2), then hold your britches and wait for mprogs to crash your mud. Generally speaking, I’ve seen no need for UPDATE_ALWAYS/Random mprog to be combined, most reasons to update without a player present, can be handled by act or specs.

GREET

Keyword : ‘GREET‘

Argument: number (percentage to trigger) NOTE: Whenever someone enters the room with the mobile, and the mobile saw the person enter, this is checked. Good for shopkeepers who want to welcome customers, or for pseudo-aggressive mobiles which need to discriminate on who they attack. Greet trigger activates only when the mobile is not busy (fighting, sitting, sleeping etc.). If you want to be sure to catch all players, use grall. (note: will only greet if the mob can ‘see’ the pc.)

GRALL

Keyword : ‘GRALL‘

Argument: number (percentage to trigger) NOTE: Like greet, but it can be triggered even if the mobile didn’t see the arrival (i.e. sneak, invis, etc) or is busy. Most useful for faking teleport rooms or for impassable guardians. IE ‘addmprog 1234 grall 75’, mprog triggers 75% of the time when pc enters.

ENTRY

Keyword : ‘ENTRY‘

Argument: number (percentage to trigger) NOTE: The opposite of greet trigger. Whenever the mobile itself enters a new room, this can be triggered. Useful for looking around, or waving or other things that real PCs do when they arrive at a crowded room. IMPORTANT: In an entry program, the mobile can only refer to a random pc ($r in if checks) — there’s no way to know how many PCs exist in the room the mobile enters! Also, you must check visibility of the target in your program.

EXIT/EXIT ALL

Keyword : ‘EXIT‘

Argument: number (0:north, 1:east, 2:south 3:west 4:up 5:down) NOTE: The opposite of entry trigger. This is activated when PC tries to leave a room through an exit indicated by the argument, and the mobile sees the person leave. Useful for having a single guardian to watch several exits. An exit trigger works better than an entry trigger, since you can refer to a specific PC instead of a random PC. IMPORTANT: If this event is triggered, the victim will not move through the exit. If necessary, you must move the character yourself in your program (see MOB TRANSFER/MOB GTRANSFER). Also, this event is not triggered when a character flees from combat or the mobile is not in its default position. IE ‘addmprog 1234 EXIT 0 100’ always activates the mprog when a pc tries to exit to the north of the mob (if pc is able to be seen by mob)

EXALL

Keyword : ‘EXALL‘

Argument: number (0:north, 1:east, 2:south 3:west 4:up 5:down) NOTE: The same as exit trigger, but it can be triggered even if the mobile cannot see the person trying to leave the room or if the mobile is busy.

GIVE

Keyword : ‘GIVE‘

Argument: string or object vnum NOTE: The argument is either the a string containing words to be matched against the keywords of the object, or the word “all”; e.g. argument “long sword” will match to objects “long bow” and “small sword”. Alternatively, the argument can be the virtual number of a single object. This is triggered whenever something is given to the mobile. Often used for quests. Since the first successful trigger is the only one of this type which is processed, having an “all” argument in the script at the end of the MOB program list is essentially a default response. IE ‘addmprog 1234 give food’ triggers whenever someone gives the mob something with keyname or type food.

BRIBE

Keyword : ‘BRIBE‘

Argument: number (The argument is any positive integer number.) NOTE: This trigger is activated whenever money is given to the mobile. If the amount given exceeds the number, then process the commands. Note again, that an argument of ‘1’ would act as a default response. Also note that if the script is not triggered (because of too little money having been given), the mobile still keeps the money, unless you make an if_check for money $i combined with a money purging or mob replacement upon trigger. (Gets tricky, don’t ask ;p) ROM 2.4 NOTE: Since ROM 2.4 has two different types of currency (gold and silver [copper and gold in Ansalon] coins), for bribe trigger the amount to be given is converted to copper coins with the rate of 1 gold = 100 copper. Thus, the number in the argument should be the expected amount in copper coins. Coin Values 1 pp = 100 st = 10,000 sp = 1,000,000 gp = 100,000,000 cp 1 st = 100 sp = 10,000 gp = 1,000,000 cp 1 sp = 100 gp = 10,000 cp 1 gp = 100 cp

KILL

Keyword : ‘KILL‘

Argument: number (percentage to trigger) NOTE: This trigger is checked whenever a PC attacks the mobile. The check occurs only ONCE, in the beginning of combat. Useful for summoning assistance etc. (See MOB LOAD).

FIGHT

Keyword : ‘FIGHT‘

Argument: number (percentage to trigger) NOTE: Useful for giving mobiles combat attitude. It is checked every PULSE_VIOLENCE when the mobile is fighting. Can be used to cast spells (see MOB CAST), curse at the opponent, or whatever. Only the first successful one will be processed to save time. Also, this means that the mobile wont get lucky and 1. curse, cast a fireball and 2. spit on the player, cast another fireball in the same pulse.

HIT POINT PERCENTAGE

Keyword : ‘HPCNT‘

Argument: number (percentage of hp to trigger) NOTE: Is activated at each PULSE_VIOLENCE when the mobile is fighting. It checks to see if the hitpoints of the mobile are below the given percentage. Multiple hpcnt triggers should be listed in increasing order of percent since a 40% will always be activated before a 20% and, only the first successful trigger is performed. (See also MOB FLEE). IE ‘addmprog 1234 hpcnt 20’ has the mob activate mprog at 20% or less of hp.

DEATH

Keyword : ‘DEATH‘

Argument: number (percentage to trigger) NOTE: When the mobile dies, if the random percentage is less than the argument the mobile performs the MOB PROGRAM commands rather than the usual death_cry() sequence. This is done before the corpse is made, so the commands can be considered the mobiles last gasp. It could perhaps destroy the items it was holding (see MOB REMOVE and MOB JUNK), or create some (see MOB OLOAD), or cast a spell (see MOB CAST) on the killer and the room, or even goto a new location (see MOB GOTO) and die there (with a text message, the corpse would seem to vanish) The position of the mobile is set to STANDING, and so it can do all the normal commands, without worrying about being DEAD. However, even if the mobile restores itself to full hit points, it will still die. This is not a way to immortal mobiles. However, the last thing this mobile does could be to goto some vacant room, load a fresh version of itself, drop all its items, force the new mobile to get all the items and wear them, send the new mobile back to the character who killed it and force the new mobile to attack that character. Along with a text message which said the mobile restored itself, this might be a convincing effect. (Note that your kitten could turn into a dragon this way too).

DELAY

Keyword : ‘DELAY‘

Argument: number NOTE: This trigger activates when the delay of a mobile (set with the MOB DELAY command) expires. This trigger can be used to create staged mobile behavior, for example, a guardian could see a player entering a room, give a warning and activate a delay. If the player is still present when the delay expires, the guard would attack the player. (See also MOB REMEMBER). A mobile can have several delay triggers, but every time the delay timer expires, all the triggers are checked and the first successful one executed.

Nesting IF_CHECKs within Programs:-==================================- Note: Every IF requires a ENDIF, like in regular programming you must close every brace.

IF  firstcheck goes here
  IF  secondcheck here (this only happens if firstcheck succeeds)
    IF thirdcheck here (this only happens if firstcheck AND secondcheck succeed)
      DO something if  all of the checks pass
    ELSE
      Here, we do something if first, and second pass, but not third
    ENDIF // close the if thirdcheck
  ELSE // second check failed, but first passed right?
    Do something if just the second check passed, or just endif
  ENDIF // end of secondcheck
ELSE // Ok, firstcheck didn't pass, so we didn't even check the other two
  insert assloads of other checks or just say 'hey didn't work
ENDIF // End of the entire statement

You CAN add other ifchecks right after, but they will always fire unless you put an END (not endif) after some successful check above.

This check is a value comparison.
Is the (STAT) of the player >=< the argument.

-=====-
Options: PC_STR, PC_INT, PC_WIS, PC_DEX, PC_CON
Syntax:

if PC_STR $n >= 18
  say You are quite buff $N!
else
  say Better hit the weights $N.
endif

This check is a value comparison. Is the trained/permanent (STAT) of the player >=< the argument.
-=====-
Syntax:

if PC_PERMSTR $n >= 18
 say You are naturally very strong $N!
else
 say Better hit the weights $N.
endif

Valid if_checks:
PC_PERMSTR, PC_PERMINT, PC_PERMWIS, PC_PERMDEX, PC_PERMCON

This check is a value comparison. Is the Hours played of the player >=< the argument.
-=====-
Syntax:

if PC_HOURS $n >= 200
  say Holy crap $N! You've been playing for ages.
else
  say Play a while $N, you might like the place.
endif

This check is a value comparison. Is the BANK (COIN) of the player >=< the argument.
-=====-
Syntax:

if PC_BCOPPER $n >= 200
  say Holy crap $N! You have over 200 steel in the bank!
else
  say You don't have very much money in the bank $N.
endif

Valid if_checks:
PC_BCOPPER, PC_BGOLD, PC_BSILVER, PC_BSTEEL, PC_BPLAT

This check is a value comparison. Is the Weight check of the player >=< the argument.
-=====-
Syntax:>

if PC_WEIGHT $n >= 600
  say Holy crap $N, you weigh over 600 pounds!
else
  say You aren't too heavy yet $N.
endif

This check is a value comparison. Is the clanlevel check of the player >=< the argument.
-=====-
Syntax:

if PC_CLANLEVEL $n >= 8
  say You are a recruiter $N.
else
  say You better go talk to the boss $N.
endif

This check looks to see which subclan a player is in, only on PC’s.

Use subclan1 for primary clan, subclan2 for secondary clan.
-=====-
Syntax:

if clan $n dragonarmy
  if pc_subclan1 $n 1
    say Welcome You Green Bastard $N!
  else
  if pc_subclan1 $n 2
    say Welcome You White DA stud $N!
  else
  if pc_subclan1 $n 3
    say Welcome You Black dog, you $N!
  else
    say I can't figure out what subclan you are $N.
  endif
  endif
  endif
else
  say You aren't in Dragonarmies $N!
endif

NOTE: You can use either subclan1 or the subclan name for the argument.

This check is simple, is the player a player killer?
-=====-
Syntax:

if pc_ispk $n
  say You are a player killer!!!
  cringe $n
else
  say Hmm, scared of a little battle $n?
endif

This check is a string comparison. Is the a players god the argument.
-=====-
Syntax:

if pc_god $n Paladine
  say You worship the Platinum Dragon!!!
  bow $n
else
  say Hello there non-believer!
endif

This check is a value comparison. Is the a random number >= the argument.
-=====-
Syntax:

if RAND 30
  say Hey, I got 30 or under in my roll!
else
  say I rolled over 30.
endif

This check is simple, Is the victim a mob?
-=====-
Syntax:

if ISNPC $n
  say Hey, you're a mob, go away.
else
  say You're a player!
endif

This check is simple, Is the victim a player character?
-=====-
Syntax:

if ISPC $n
  say You're a player!
else
  say Hey, you're a mob, go away.
endif

This check is a value comparison, Is the victim good? (alignment number check)
-=====-
Syntax:

if ISGOOD $n
  say You're a goody two-shoes, You're a goody two-shoes.
  emote dances around
  emote pokes you in the eye.
else
  say You aren't a goody goody.
  sniff
endif

This check is a value comparison, Is the victim evil? (alignment number check)
-=====-
Syntax:

if ISEVIL $n
  say You are Soooooo Evil $N!!
  cower $n
else
  say You aren't bad at all $N.
  smile
endif

This check is a value comparison, Is the victim neutral? (alignment number
check)
-=====-
Syntax:

if ISNEUTRAL $n
  say You are quite neutral $N.
else
  say You must be good or evil $N.
  emote looks at you with a suspicious sidelong glance.
endif

This check is a value comparison, Is the victim’s level above hero? (102+)
-=====-
Syntax:

if ISIMMORT $n
  say Hello there your godliness $N.
else
  say You are a mortal!
  say You will DIE $N!!!
  MOB kill $n
endif

NOTE: Very useful if you have a GRALL program and don’t want immortals to
have it trigger. Or have a program to damage players, leaves imms alone.

This check is simple, Is the victim charmed?
-=====-
Syntax:

if ISCHARMED $n
  say Not thinking for yourself lately I see, who's your master $N?
else
  say You have much free will $N.
endif

This check is simple, Is the victim following someone here?
-=====-
Syntax:

if ISFOLLOW $n
  nod $n
  say You may pass, but don't come here unescorted $N.
else
  say You don't belong here $N!!
  mob transfer $N pole
endif

NOTE: This is useful for clans (escort), for prisons etc.

if ISVIOLENT $n
  shake $n
  say You are too riled up to come in here $N.
else
  say Welcome $N!!
  mob transfer $N 
endif

if MOBHERE tarantula
  mob force tarantula mob kill $n
else
  say Damn, if my spider was here, you'd be toast $N.
endif

if OJBHERE table
  sit table
else
  say Damn, did you take my table $R.
endif

if PEOPLE >= 5
  say Wow, we're getting full in here.
else
  say The place seems pretty deserted doesn't it $N?
endif

if PLAYERS >= 2
  say Quite a few players here.
else
  say You're the only player here $N.
endif

if MOBS >= 2
  say Quite a few mobs here $N.
  say Why don't you kill some?
else
  say Not very many mobs here $N.
endif

if MOBEXISTS Julia
  say You should go talk to Julia $N.
else
  say Julia must not be around $N.
endif

if OBJEXISTS whitegold
  say Sorry $N, you can't have one, someone already has a White Gold Ring.
else
  say Oh sure, take my nice ring $N.
  mob oload 1342134 0 none
  give ring $n.
endif

if clones >= 4
  say More than four!
else
  if clones == 3
    say Exactly three, plus me!
  else
    if clones == 2
      say Exactly two, plus me!
    else
      if clones == 1
        say Just one clone of me!
      else
        if clones == 0
          say Not just me!
        else
          say Just me!
        endif
      endif
    endif
  endif
endif

if ORDER $n >= 2
  say Why don't you ask your master $N?
else
  say Ahh, you are the boss $N.
endif

if HOUR >= 8
  say Wow, it's past eight already.
else
  say Sorry, I don't do squat until 8 am $N.
endif

if ISACTIVE $i
  say Hey, I'm awake already.
else
  rest
  stand
  emote looks around with bleary eyes.
endif

if language $i goblin
  say I'm speaking goblin, you fool you can't understand me.
else
  say I'm uh, not speaking goblin!
endif

If language $n silvanesti
  say My greetings $n, that is the correct password.
  MOB TRANS $n 1234
else
  language silvantesti
  say I only speak Silvanesti you uncouth heathen.
endif

if POS $i fighting
  say Hey, I'm kind of busy here $N, please come back later.
else
  say Hey, I'm not fighting, wanna brawl $N?
endif

if ISDELAY $i
  say Sorry $N, I'm busy already.
else
  mob remember $n
  mob delay 20
endif

if ISVISIBLE $n
  say I can seeeee you!
else
  say Hey, who's there?
endif

if HASTARGET $i
  say Hey, have you seen $Q $N?
else
  say Hey, I'll remember you $N!
  mob remember $n
endif

if ISTARGET $n
  say Hey, just the man I've been looking for $Q!
  mob kill $Q
  mob forget
else
  say You're not who I'm looking for $N, I'm after $Q.
endif

if EXISTS $q
  mob at $q mob echoat $q Time to come home $Q.
  mob at $q mob echoaround $q $I comes to take $Q home for dinner.
  mob at $q mob transfer $q 12151
else
  say My victim has left the game.
  mob forget.
endif

if AFFECTED $n fly
  mob echo You float across the water.
else
  mob echo You begin to drown in the pool!
  mob damage $n 100 200 lethal
endif

NOTE: Can also be used to have the mob see if it is affected by spells etc.
IE.

if AFFECTED $i haste
  break
else
  eat pill
endif

if ACT $i warrior
  flex
  say I'm a tough warrior.
  mob kill $n
else
  say I'm much to wimpy to fight you $N.
endif

if OFF $i dirtkick
  emote looks at the ground.
  dirt $n
else
  say You know, I'd kick dirt on you if I could.
  grumble
endif

if IMM $n magic
  say Damnit, my magic can't harm you $N.
  emote slashes at you with a dagger instead.
else
  say Ha ha!
  mob cast fireball $n
endif

if CARRIES $n sword
  say That's a nice sword you have there $N.
else
  say You should go buy a sword.
endif

if WEARS $n holy symbol
  bow $n
  say Welcome to our humble sanctuary $N.
else
  say You shouldn't be here $N.
  mob force $N south
endif

if HAS $n dagger
  if WEARS $n dagger
    say That dagger looks real sharp $N.
  else
    say Your dagger would be better used in your hand $N.
    mob force $n wear dagger
  endif
else
  say You should go buy a dagger $N.
endif

if USES $n light
  say Not so dark is it $N?
else
  say Nyyaaa, it's dark and you can't see me!
endif

if NAME $o pie
  say Yum, what a tasty pie!
  eat pie
else
  say Hey, this is an $O, I wanted a pie!
endif

if CLAN $n kot
  salute $n
  say Welcome home $N.
else
  say Hey, you aren't a Knight of Takhisis!!
  scream
  mob kill $n
endif

if RACE $n gnome
  grumble
  say Wherehaveyoubeen$N?
else
  say You aren't a gnome, want to see the flinger?
endif

if CLASS $n thief
  say You are a thief, come on in and take my stuff!
else
  say Whew, you aren't a thief, you had me worried $N.
endif

if OBJTYPE $o food
  say Thanks, I was very hungry!
  eat $o
  say Mmmm, that $O was delicious $N!
else
  say This isn't food!
  drop $o
  emote hops around rubbing $k tummy.
endif

if VNUM $i 12345
  say I am a strong guard.
  flex
else
  say I am a ninny squire!
  say I wish I was a guard.
endif

if HPCNT $i >= 30
  say Damn $N, you're kicking my ass!
else
  say I'm not quite dead!
endif

if ROOM $i == 12345
  say I am standing in the East Wing.
  push $n west
else
  if ROOM $i == 12346
    say I am standing in the West Wing.
    push $n east
  else
    say I'm not in my room.
    sniff
  endif
endif

 (1 is male, 2 is female, 0 is 'IT')
if SEX $n == 1
  say Hey there big boy.
else
  if SEX $n == 2
    say Hey there hot mamma.
  else
    say Oh my god!
    say You're an IT!!!!
  endif
endif

if LEVEL $n >= 5
  say You're sure getting up there in levels $N.
else
  say You need to go level $N!
endif

if ALIGN $n >= 0
  say You aren't so bad.
else
  say You aren't so good.
endif

if MONEY $i >= 300
  say I'm pretty rich
else
  say Dang, I dont have much money.
  emote Opens a safe.
  mob oload 12314 0 room
  get coins
  say Now I'm rich!
endif

if OBJVAL $o >= 300
  say This is quite nice.
else
  say This is a piece of junk.
  say Who would want a $O?
endif

if GRPSIZE $n >= 7
  say Hello there your lordship.
else
  say Hehe, you don't look so tough.
  mob kill $n
endif

 
if STATUS $i == 0
  say My status is 0, going to 1
  MOB STATUS 1
  end // We add these END to stop it from continuing
  //as mob status would be 1 after this and trigger more
endif 
if STATUS $i == 1 
  say My STATUS is 1, going to 2
  MOB STATUS 2
  end 
endif
if STATUS $i == 2
  say My STATUS is 2, going to 0
  MOB STATUS 0
  end
endif
end

Operators

Most of the basic numeric operators are legal and perform the same
function as in C.

Operators:

If_Checks In Control Flow (Summary)

The provided list of if_checks and their arguments are below. They
should all be fairly obvious in what they do, but some of the more obtuse
deserve a slight explanation. Any '==' operator can be replaced with any of
the available ones described above. The argument $* refers to any of the
variables which make sense for that if_check (i.e. for an if_check which is
referencing a person the only valid variables would be $i, $n, $t, $r or $q)
A value type of string is a sequence of characters. It does not need to be
included in quotes or anything like that (i.e. if name $n fido )

There are five types of if checks:

Type 1: Keyword/value Explanation

rand num          - Is random percentage less than or equal to num
mobhere vnum      - Is a NPC with this vnum in the room
mobhere name      - Is a NPC with this name in the room
objhere vnum      - Is an object with this vnum in the room
objhere name      - Is an object with this name in the room
mobexists name    - Does NPC 'name' exist somewhere in the world
objexists name    - Does object 'name' exist somewhere in the world

Type 2: Keyword/compare/value Explanation

people == integer  - Is the number of people in the room equal to integer
players == integer - Is the number of PCs in the room equal to integer
mobs == integer    - Is the number of NPCs in the room equal to integer
clones == integer  - Is the number of NPCs in the room with the same
                     vnum as the NPC who activated the program equal
                     to integer
order == integer   - Is the order (of several similar NPCs) of the NPC
                     who activated the trigger equal to integer
hour == integer    - Is the hour (game time) equal to integer

Type 3: Keyword/actor Explanation

isnpc $* - Is $* an NPC
ispc $* - Is $* a PC
isgood $* - Does $* have a good alignment
isneutral $* - Does $* have a neutral alignment
isevil $* - Does $* have an evil alignment
isimmort $* - Is $* an immortal (level of $* > LEVEL_HERO)
ischarm $* - Is $* affected by charm
isfollow $* - Is $* a follower with their master in the room
isactive $* - Is $*'s position > POS_SLEEPING
isdelay $* - Does $* have a delayed MOB PROGRAM pending
isvisible $* - Is $* visible to NPC who activated the program
hastarget $* - Does $* have a MOB PROGRAM target in the room
istarget $* - Is $* the target of NPC who activated the program

Type 4: Keyword/actor/value Explanation

affected $* 'affect' - Is $* affected by 'affect'
act $* 'act' - Is $*'s ACT bit 'act' set
off $* 'off' - Is $*'s OFF bit 'off' set
imm $* 'imm' - Is $*'s IMM bit 'imm' set
carries $* 'name' - Is $* carrying object 'name'
wears $* 'name' - Is $* wearing object 'name'
has $* 'type' - Does $* have object of item_type 'type'
uses $* 'type' - Is $* wearing object of item_type 'type'
name $* 'name' - Is $*'s name 'name'
pos $* 'position' - Is $*'s position 'position' (sleeping etc.)
clan $* 'name' - Does $* belong to clan 'name'
race $* 'name' - Is $* of race 'name'
class $* 'name' - Is $*'s class 'name'
objtype $* 'type' - Is $*'s item_type 'type'

Type 5: Keyword, actor, comparison and value

vnum $* == integer - Is $*'s virtual number equal to integer
hpcnt $* == integer - Is $*'s hitpoint percentage equal to integer
room $* == integer - Is vnum of the room $* is in equal to integer
sex $* == integer - Is $*'s sex equal to integer
level $* == integer - Is $*'s level equal to integer
align $* == integer - Is $*'s alignment equal to integer
money $* == integer - Does $* have money (in gold) equal to integer
objval# $* == integer - Is $*->value[#] equal to integer (# from 0-4)

NOTE: The original MERC 2.2 MOBprograms used parenthesis ‘(‘ and ‘)’ around variables. In this version, they are NOT allowed. Also, parameters MUST BE separated with spaces (Correct syntax is: if level $n < 10).

Mob Command List

Each MOBcommand must be preceeded by "MOB"
For Example:
MOB ECHOAT $n [string]

MOB Command argument_list Explanation

MLOAD (mobile) – Lets the mobile load another mobile.

OLOAD (obj vnum) (level) (location) – Lets the mobile load an object
2ND ARGUMENT
# – the level to load the object at
Use 0 if you wish to continue building.
3RD ARGUMENT
None – inventory
R – in room (can also use Room)
W – on mob (must be hold/wearable)
KILL (victim) – Lets the mobile kill any player or mobile
without murder
PEACE – Stops all fighting in that room
ASSIST (victim) – Lets the mobile assist another mob or player
MPDUMP 1234 – Displays the source code of a given MOB PROGRAM
ECHO (text_string) – Prints the message to the room at large
ECHOAT (victim) [string] – Prints the message to only the victim
ECHOAROUND (victim) [string] – Prints the message to everyone in the room other
VECHO (room vnum> [string] – Echo a string at a specific room
MVECHO (vnum vnum> [string] – Echo a string at a specific RANGE of rooms
GECHO (text_string) – Prints the argument to all active players
ZECHO (text_string) – Prints the argument to all players in the
same area as the mob
ASOUND (text_string) – Prints the argument to all the rooms around the mobile
than the mob and victim
PURGE (target) – Lets the mobile purge all objects and other
npcs in the room, or purge a specified object
or mob in the room. The mobile can
purge itself, but it must be the last command.
GOTO (dest) – Lets the mobile goto any location it wishes
that is not private.
AT (location) [commands] – Lets the mobile do a command at another location.
TRANSFER (target|’all’) [location]- Lets the mobile transfer people. The ‘all’
argument transfers everyone in the current
room to the specified location
(room vnum or mobile name)
SLIP (target|’all’) [location]- Lets the mobile slip people. The ‘all’
argument transfers everyone in the current
room to the specified location
(room vnum or mobile name)
NOTE: This is a transfer, but there is no
‘look’ so the PC won’t know it happened.
GRTRANSFER (victim) [location] – Lets the mobile transfer all chars in same group
as the victim.
OTRANSFER (item name) [location] – Lets the mobile to transfer an object. The object
must be in the same room with the mobile.
REMOVE (victim) [object vnum|’all’]- Lets the mobile to strip an object or all objects
from the victim. Useful for removing e.g.
quest objects from a character.
JUNK (object) – Lets the mobile destroy an object in
its inventory
– it can also destroy a worn object and
it can destroy items using all.xxxxx
or just plain all of them
FORCE (victim) [commands] – Lets the mobile force someone to do something.
Must be mortal level and the all argument only
affects those in the room with the mobile.
GFORCE (victim) [commands] – Lets the mobile force a group something. Must be
mortal level.
VFORCE 1234 [commands] – Forces all mobiles of certain vnum to do something
CAST (spell) [target] – Lets the mobile cast spells —
Beware: this does only crude checking on the target
validity and does not account for mana etc., so
you should do all the necessary checking in your
mob program before issuing this cmd!
DAMAGE (victim) [min] [max] (kill)- Lets mob cause unconditional damage to someone.
Nasty, use with caution.  Also, this is silent, you must show your own damage message. If kill parameter is omitted, this command is “safe” and will not kill the victim.  REMEMBER (victim) – Lets the mobile to remember a target. The target can
be referred to with $q and $Q codes in MOBprograms.  See also “mob forget”.
FORGET (victim) – Reverse of “mob remember”.
DELAY (pulses) – Sets a delay for MOB PROGRAM execution. When the delay time expires, the mobile is checked for a mob program with DELAY trigger, and if one is
found, it is executed. Delay is counted in PULSE_MOBILE
CANCEL – Reverse of “mob delay”, deactivates the timer.

CALL [vnum] [victim|’null’] [object1|’null’] [object2|’null’] – Lets the mobile to call  another MOB PROGRAM withing a MOB PROGRAM.  This is a crude way to implement subroutines/functions. Beware of nested loops and unwanted triggerings… Stack usage might be a problem.  Characters and objects referred to must be in the same room with the mobile.

FLEE – Forces the mobile to flee.
STATUS – An integar the mob can set/change on itself.
PORTALTO (vnum to) (portal used)- This command let’s a mob create a portal
between the room it’s in, and the room you specify (if you specify a portal then it uses THAT one, so you can use a specific gangplank, door etc).

CREATE – Used to create random objects, amounts of money or gems as rewards for quests.

GOTORESET No argument used, this will take the mob back to
the room that it loaded in, it’s reset room.

MOBcommands are special commands that allow mobiles to perform
immortal-like actions within a MOB PROGRAM (transferring players
or loading items, for example). Most MOBcommands them are wiz
commands which have been changed to allow for mobiles to perform
the commands. In this version of MOBprograms, players have been
prevented from using these commands by adding a separate
interpreter for MOBcommands. This also speeds up (in most cases)
MOB PROGRAM execution when MOBcommands are used. All MOBcommands
are preceded with the word ‘MOB’ on the command line.

MOB STATUS [int]

NOTE:

STATUS lets you put mobiles in different states, this is
simply an integar you attach to them, and can check on them.

Syntax Example:
if STATUS $i == 0
say My status is 0, going to 1
MOB STATUS 1
end
endif
if STATUS $i == 1
say My STATUS is 1, going to 2
MOB STATUS 2
end
endif
if STATUS $i == 2
say My STATUS is 2, going to 0
MOB STATUS 0
end
endif
end

Note: (the ‘end’ in each check, good thing, or the mob will keep going)
This command can make the mob MUCH more intelligent to react with.
Many thanks to Tyche.

MOB ASOUND [string]
MOB ZECHO [string]
MOB GECHO [string]

NOTE:

ASOUND prints the text string to the rooms around the mobile in
the same manner as a death cry. This is really useful for
powerful aggressives and is also nice for wandering minstrels or
mobiles like that in concept. (Or certain gnomish contraptions ;0)

ZECHO prints the string to all players in the same area with the
mobile. Short for Zone Echo.

GECHO prints the string to all players in the game. Short for Global Echo.

MOB ECHO [string]
MOB ECHOAT [victim] [string]
MOB ECHOAROUND [victim] [string]

Note:
ECHO displays the string to everyone in the room.

ECHOAT displays the string to the victim only.

ECHOAROUND displays the string to everyone except the victim.

The three options let you tailor the message to goto victims or
to do things sneaky like having a merchant do: mob at guard mob
echoat guard rescue_please This coupled with a guard act trigger
on rescue_please to: mob goto $n mob echo $I has arrived. It is
an affective way of quickly bringing guards to the scene of an
attack. (Note that the merchant has to be the only one of its
kind in the game or have a unique name, otherwise the guard
might go to different mobile…).

MOB MLOAD [vnum]
MOB OLOAD [vnum] {‘room’|’wear’}
(without second argument, loads in inventory)

IE: MOB OLOAD 16203 0 WEAR // Loads it, wears It if it can
IE: MOB OLOAD 16203 0 ROOM // Loads it in the ROOM
IE: MOB OLOAD 16203 0 NONE // Loads it in inventory

Note:
MLOAD creates a mobile and places it in the same room with the
mobile. OLOAD loads the object into the inventory of the mobile.
Even if the item is non-takable, the mobile will receive it in
the inventory. This lets a mobile distribute a quest item or
load a key or something. The optional 3rd parameter can be
specified; ‘room’ means to load the object to the room, ‘wear’
means to force the mobile to wear the object loaded (useful for
equipping mobiles on the fly).

MOB KILL [victim]

Note:
Lets a mobile kill a player without having to murder. Many
MOBprograms end up with mob kill $n commands floating around. It
works on both mobiles and players.

MOB FLEE

Note:
Causes a mobile to unconditionally flee from combat. Can be used
for example with the hit point percentage trigger to simulate
“wimpy” behavior.

MOB REMOVE [victim] [vnum|’all’]

Note:
Lets the mobile to strip an object of given vnum from the
victim. Objects removed are destroyed. If the vnum is replaced
with “all”, the whole inventory of the victim is destroyed. This
command is probably most useful for extracting quest items from
a player after a quest has been completed.

MOB JUNK [object]

Note:
Destroys the object referred to in the mobile’s inventory. It
prints no message to the world and you can do things like junk
all.bread or junk all. This is nice for having janitor mobiles
clean out their inventory if they are carrying too much (have a
MOB PROGRAM trigger on the ‘full inventory’)

MOB PURGE [argument]

Note:
Destroys the argument from the room of the mobile. Without an
argument the result is the cleansing of all NPC’s and items from
the room with the exception of the mobile itself. However,
mppurge $i will indeed purge the mobile, but it MUST be the last
command the mobile tries to do, otherwise the mud cant reference
the acting mobile trying to do the commands and bad things
happen.

MOB AT [location] [command]

Note:
Performs the command at the designated location. Very useful for
doing magic slight of hand tricks that leave players dumbfounded..
such as metamorphing mobiles, or guard summoning, or corpse
vanishing.

MOB GOTO [location]

Note:
Moves the mobile to the room or mobile or object requested. It
makes no message of its departure or of its entrance, so these
must be supplied with echo commands if they are desired.

MOB TRANSFER [victim/’all’] [location]
MOB GTRANSFER [victim] [location]
MOB OTRANSFER [object] [location]

Note:
Sends the victim to the destination or to the room of the mobile
as a default. if the victim is “all” then all the characters in
the room of the mobile are transferred to the destination. Good
for starting quests or things like that. There is no message
given to the player that it has been transferred and the player
doesn’t do a look at the new room unless the mob forces them to.

Gtransfer works like transfer, except that the group the victim
belongs to is transferred with the victim. Otransfer
transfers an object in the room.

MOB FORCE [victim/’all’] [command]
MOB GFORCE [victim] [command]
MOB VFORCE [vnum] [command] ***** Didn’t seem to work on Ansalon

Note:
Forces the victim to do the designated command. The victim is
not told that they are forced, they just do the command so
usually some MOB ECHO message is nice. You can force players to
remove belongings and give them to you, etc. The player sees
the normal command messages (such as removing the item and
giving it away in the above example) Again, if the victim is
“all” then everyone in the mobiles room does the command. Gforce
works like force except that it affects the group the victim
belongs to.

Vforce affects all mobiles with given vnum in the game world.
This is useful for, for example, purging certain type of NPCs
from the game (by forcing them to purge themselves).

MOB CAST [spell] [victim]

Note:
Lets the mobile to cast spells. Beware, this does only crude
validity checking and does not use up any mana. All spells are
available regardless of the race or other abilities of the
mobile. Casting the spell occurs silently, but spell effects are
displayed normally.

MOB DAMAGE [victim/’all’] [min] [max] {lethal}

Note:
Causes unconditional damage to the victim. Specifying “all” as
victim causes damage to all characters in the room except the
mobile. Min and max parameters define the minimum and maximum
amounts of damage caused. By default, the damage is non-lethal,
but by supplying the optional ‘lethal’ parameter, the damage can
kill the victim. This command is silent, you must echo all
messages yourself in the program. Useful for implementing
special attacks for mobiles.

MOB DELAY
MOB CANCEL

Note:
MOB DELAY sets the time in PULSE_MOBILE after which the mobile’s
delay trigger is activated. If the mobile has a program defined
for delay trigger, the program is executed when the timer expires.

MOB CANCEL resets the delay timer.

MOB REMEMBER [victim]
MOB FORGET

Note:
This command enables the mobile to remember a player for future
reference in a MOB PROGRAM. The player can subsequently be
referred as ‘$q’ in programs activated by the mobile. MOB FORGET
clears the target. Note that if the first time the mobile runs a
program, $q is automatically set to the player who triggered the
event. Most commonly this command is used in delayed programs,
where the mobile has to remember the player who triggered the
original event, for example to continue conversation.

MOB CALL [vnum] {victim} {target1} {target2}

Note:
This command lets you call MOBprograms from within a running
one, i.e. to call a MOB PROGRAM subroutine. The first parameter
is the vnum of the program to execute, the second is the
victim’s name (for example $n), and the third and fourth are
optional object names. All other parameters except vnum can be
replaced with word ‘null’ indicating ignored parameter.

MOBprograms can be called recursively, but as a safety measure,
parser allows only 5 recursions (unless altered).

MOB PORTALTO [vnum][portal vnum]

Note:
This command lets mobs link areas with portals, if you don’t
specify a portal (or use #25) it will vape in 10 ticks.

Example: We have a new gangplank portal named gangplank trsgp
(Pick a UNIQUE name if you want the mob to be able to find/purge old ones)

if objexists trsgp
    mob at trsgp mob purge trsgp
   endif
   if objexists trsgp
     mob at trsgp mob purge trsgp
   endif
   say Thanks, we're just arriving at the docks of Caergoth now!
   mob portalto 16200 13610
   mob echo A sailor pushes a gangplank off the stern onto the docks at Caergoth.
   mob vecho 16200 A sailor ties off the Percheron and pushes a gangplank to the dock.
   mob junk ticket

MOB CREATE $n [type] [arguments]

Note: Types are equip, money or gem and arguments for each are below:

equip : green, red, white

gem: diamond, ruby, emerald, opal, pearl, garnet

money: low value, high value

Example: You can have a miniquest mob generate random prizes now.

  if $N has questobject
    say Thank you so much for completing the quest $n!
    mob junk questobject
    mob create $n equip green
    mob create $n money 250 350
    mob create $n gem garnet
   endif

Attaching Mprogs to Mobs

Commands within Medit (while editing a mob, AFTER mprog created)

addmprog [vnum] [trigger] [phrase]

Example: (with a mob being edited)(medit)
addmprog 13456 greet 80 – This adds mprog 13456 to the mobile,
which greets pc’s when they enter
80% of the time.
delmprog 0 (or 1,2,3 etc) – removes an mprog from a mob.

NOTE:
[vnum] The vnum of the mob program (mpedit)
[trigger] List of valid triggers and explanations above
[phrase] A single word, or a phrase within quotes
(example: “looks at you” or “yes” etc)
Or a percentile (ie ’80’ happens 80% of the time)

Loading Mobiles and Objects

No doubt you want to load objects and mobiles in your MOBprograms
with “mob oload” and “mob mload”. There are two problems connected
to this. One is that mloaded mobiles will appear without equipment
and the other is that it is difficult to keep track of the number of
created mobiles and objects.

If you want to mobiles to appear in your area as a result of the
players’ action, create a “storage room”. Define resets for the
mobiles as usual (equipment etc.) and place them in the storage
room. When you need to use the mobiles, just “mob transfer” them to
the location you want. This is better than creating mobiles on the
fly, since you don’t have to worry about creating too many mobiles
or equipping them, area resets take care of all that.

If you have a MOB PROGRAM that creates new mobiles, you might want
to make the mobiles “self-destructing”. This is easiest to do with a
random trigger that checks if the mobile is doing anything useful
and possibly does ‘mob purge $i’.

Another possibility is to use a “purgemaster”. Create a storage room
with a single mobile. Attach a random trigger that does ‘mob purge’
to that mobile. Now, when you need to get rid of anything, just ‘mob
transfer’ the mobile or item to purgemaster, and it will be
destroyed sometime later.

Miscellaneous Information

There is really no limit to the number of MOBprograms a given mobile
can have. However, the length of a single command block is limited
by the value of MAX_STRING_LENGTH. In my version it was around 4k,
so that is probably about 100 lines. The indentation spaces shown
in the example above are NOT required, but do make it easier to read
(and debug). HOWEVER, all spaces and indentations are loaded into
memory as a part of the program, so you’re using up memory.
Memory usage can also be reduced by using subroutines
(see MOB CALL).

It IS possible to accidentally make mobiles which can trigger in
loops. Infinite loops have been prevented, but in case of a loop,
the mobile behavior is undefined. An example of a looping action
would be using a RANDOM mprog with an UPDATE_ALWAYS mob, this
doesn’t actually loop, but may cause this error:
[*****] BUG: MOBprogs: MAX_CALL_LEVEL exceeded, vnum #
(note: vnum refers to calling mob’s vnum NOT mprog vnum)
this is when too many mprogs are being called simultaneously, and
the rom can’t deal with them, happens with UPDATE_ALWAYS and RANDOM
trigger combinations, especially when there are 20 of the mob, each
with 3 random mprogs each, you do the math.

The list of variables and triggers and if_checks will grow
continuously as mud creators demand the ability to do certain
things. If you have a request or if you have a new one, I don’t mind
hearing about them, and if you find bugs, I shall gladly attempt to
squash them for you. As additions or fixes are made, the code will
occasionally be redistributed. However, if you want a current
version, please feel free to ask. When the code is redistributed, a
file containing the change history from the original release will be
provided (when possible) to allow you to patch in the changes with
low grief.

– Note: Who do we call again? If someone knows, please let the
immortal staff know.

CREDITS

The reason this code was written was to enhance the playing
experience at ThePrincedom (a Merc 2.0 based world scheduled to open
in October 1993)

The original idea for this type of MOB PROGRAM came from playing on:
WORLDS of CARNAGE, a DIKU MUD implemented by Robbie Roberts and
Aaron Buhr. Aaron (known as Dimwit Flathead the First) was the
original author from what I have been told, and I hope he will not
be totally offended and angered by my coding and sharing a mimicked
version with the world. This version is probably not as good as the
original and I do feel remorse for publishing the idea. However,
since Carnage has been down for months without a word of information
regarding its return, I am glad to let one of the best features live
on in future generations of MUDs.

There are no objections to this code being shared, since, aside from
a nuclear destruction of all the Temples of Midgaard (excepting the
original one!!), bland mobiles are the greatest bane of Dikumuds
today. It would be nice to get a message saying you are using the
code just for our references. We shant answer questions from anyone
until told where they are using the code. *grin* Since this code is
not copyrighted, you of course dont have to do anything we say, but
it would be nice of you to put the mobprog help screen into your
database. and have mobinfo show up somewhere on a more visible help
screen (possibly tagged onto the bottom of credits as a see also…)

I acknowledge all the work done by the original Diku authors as well
as those at Merc Industries and appreciate their willingness to
share code. Also, quick thanks to Wraith for doing a little
beta-installation testing.

N’Atas-Ha June, 1993
natasha@gs118.sp.cs.cmu.edu

In addition to this DOC file credit section, I’d like to add a thank
you to Yaz, Mahatma, Zelda, and the rest of the 4th Realm crew for
extensively testing MOB PROGRAM 2.1 for me. You may see MOBPrograms
in action as well as their own “flavor” of mud at marble.bu.edu 4000.

Kahn Oct 28th, 1993
MERC Industries

MORE CREDITS

This text was compiled from several mob prog/mpedit texts in order to give you a more complete guide to mob progs in Ansalon (Rom 2.4 based in 1996) The previous credits/copyrights are for the ‘extended’ or ‘more info’ parts which I added to the existing document to further explain functions/syntax etc.

Other notes and examples added from my trials in CRASHING MUD! As I rewrite code and write better explanations of how to use the different aspects of mobprogs, they are updated here.

Zivilyn aka Skol December 10th, 2001 – Oct 20th, 2023
Ansalon

This document was created for use with Ansalon, ROM 2.4 and OLC on…

www.Ansalon.net
telnet://ansalon.net:8679

Version 2.3.7 September 27, 2017

PS. If you run into questions/scenario’s not handled here, feel free to talk with me about them. If they are something that needs to be added or discussed, I’ll be happy to do so. – Skol.